Script Para Borrar Ficheros Viejos

Este script permite borrar los ficheros contenidos en uina carpeta cuya fecha de última modificación sea anterior a la fecha que se le pasa como parámetro.

'Este script recibe como parámetros una ruta de carpeta y una fecha en
'formato DD/MM/YYYY y borra todos aquellos ficheros ubicados en la ruta
'que indica la carpeta que tengan como fecha de última modificación
'una igual o anterior a la recibida como parámetro. Si se añade el
'modificador /R el borrado se hará en todo el árbol cuya raíz es el 
'parámetro de ruta recibido. Ejemplo: 

'cscript borrar-ficheros-hasta-fecha.vbs /R c:Carpeta 23/11/2003

'© Noviembre de 2006 - Fernando Reyes

'Febrero de 2007:
'Se añade el parámetro /R por el cual se realizará un borrado de forma
'recursiva, esto es, de la carpeta recibida y de todo el subárbol que
'contiene

Option Explicit

Dim str_Fecha
Dim bol_Recursivo
Dim str_Ruta
Dim dth_Fecha

WScript.Echo "1.- " & WScript.Arguments(0)

WScript.Echo "2.- " & WScript.Arguments(1)

'Comprobamos que hemos recibido el número correcto de parámetros
'recibidos
If WScript.Arguments.Unnamed.Count <> 2 Then


    WScript.Echo "Error 1: Número de parámetros incorrecto. " & _
          "Se deben pasar 2:" & _
          vbCrLf & vbCrLf & _
          " 1.- Ruta de la carpeta donde borrar los ficheros." & _
          vbCrLf & _
           " 2.- Fecha de última modificación a partir de la cual" & _
           vbCrLf & _
           " se borrarán los ficheros anteriores y de la misma fecha " & _
           "(DD/MM/YYYY)." & vbCrLf & vbCrLf & _
           "Se puede agregar el modificador /R para que haga " & _
           "el borrado de forma recursiva" & vbCrLf & _
           vbCrLf & _
           "Ejemplo:" & vbCrLf & vbCrLf & _
           "cscript borrar-ficheros-hasta-fecha.vbs /R " & _
           "c:Carpeta 23/11/2003"
    WScript.Quit 1

End If

If WScript.Arguments.Named.Exists("R") Then bol_Recursivo = True

str_Ruta = WScript.Arguments.Unnamed(0)
dth_Fecha = WScript.Arguments.Unnamed(1)

Call s_BorrarFicheros(str_Ruta, dth_Fecha, bol_Recursivo)

Sub s_BorrarFicheros(str_Ruta, dth_Fecha, bol_Recursivo)

    Dim obj_FSO
    Dim obj_Carpeta
    Dim obj_Fichero

    'Creamos el objeto FileSystemObject
    Set obj_FSO = CreateObject("Scripting.FileSystemObject")
    
    'Comprobamos que la ruta recibida sea válida
    If not obj_FSO.FolderExists(str_Ruta) Then
    
        WScript.Echo "Error 2: La carpeta " & str_Ruta & _
                           " recibida como parámetro no existe."
        Set obj_FSO = Nothing
        WScript.Quit 2
    
    End If
    
    'Comprobamos que la fecha recibida sea válida
    If not IsDate(dth_Fecha) Then
    
        WScript.Echo "Error 3: La fecha " & dth_Fecha & _
                     " recibida como parámetro no es una fecha válida."
        Set obj_FSO = Nothing
        WScript.Quit 3
    
    End If
    
    'Creamos el objeto carpeta
    Set obj_Carpeta = obj_FSO.GetFolder(str_Ruta)
    
    'Recorremos los ficheros contenidos en la carpeta
    For Each obj_Fichero In obj_Carpeta.Files
    
        'Comprobamos que la fecha de última modificación del fichero
        'sea anterior o igual a la recibida como parámetro
    
        If DateValue(obj_Fichero.DateLastModified) <= _
                                        DateValue(dth_Fecha) Then
    
            'En caso afirmativo, mostramos el nombre y fecha del fichero
            'y lo borramos
            WScript.Echo "Borrando " & obj_Fichero.Name & _
            ": Modificado el " & _
            obj_Fichero.DateLastModified
            'Borramos el fichero incluso en el caso de ser de sistema, si 
            'quisiéramos que  no se borren los de sistema, tan sólo
            'debemos eliminar el True o sustituirlo por False
            obj_Fichero.Delete True
    
        End If
    
    Next
    
    'Si queremos que se recorra todo el subárbol de carpetas...
    If bol_Recursivo Then

        'Definimos un objeto para las subcarpetas
        Dim obj_Subcarpeta
        
        'Recorremos las subcarpetas en este bucle
        For Each obj_Subcarpeta In obj_Carpeta.Subfolders
        
            'Llamada recursiva para borrar los ficheros de la
            'subcarpeta
            Call s_BorrarFicheros(obj_Subcarpeta.Path,dth_Fecha, _
                                         bol_Recursivo)
        
        Next
        
        Set obj_Subcarpeta = Nothing   
    
    End If
    
    'Nos limpiamos el culito antes de terminar :-))
    Set obj_Fichero = Nothing
    Set obj_Carpeta = Nothing
    Set obj_FSO = Nothing

End Sub